precision highp float;
#define iChannel0 inputImageTexture
#define texture(a,b) texture2D(a,fract(b))
#define fragColor gl_FragColor
#define Max_Rotation 0.65


varying highp vec2 textureCoordinate;

uniform sampler2D inputImageTexture;

uniform highp float iTime;

uniform highp vec2 iResolution;
vec3 mod289(vec3 x)
{
    return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 mod289(vec4 x)
{
    return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 permute(vec4 x)
{
    return mod289(((x*34.0)+1.0)*x);
}

vec4 taylorInvSqrt(vec4 r)
{
    return 1.79284291400159 - 0.85373472095314 * r;
}

float snoise(vec3 v)
{
    const vec2  C = vec2(1.0/6.0, 1.0/3.0) ;
    const vec4  D = vec4(0.0, 0.5, 1.0, 2.0);

    // First corner
    vec3 i  = floor(v + dot(v, C.yyy) );
    vec3 x0 =   v - i + dot(i, C.xxx) ;

    // Other corners
    vec3 g = step(x0.yzx, x0.xyz);
    vec3 l = 1.0 - g;
    vec3 i1 = min( g.xyz, l.zxy );
    vec3 i2 = max( g.xyz, l.zxy );

    //   x0 = x0 - 0.0 + 0.0 * C.xxx;
    //   x1 = x0 - i1  + 1.0 * C.xxx;
    //   x2 = x0 - i2  + 2.0 * C.xxx;
    //   x3 = x0 - 1.0 + 3.0 * C.xxx;
    vec3 x1 = x0 - i1 + C.xxx;
    vec3 x2 = x0 - i2 + C.yyy; // 2.0*C.x = 1/3 = C.y
    vec3 x3 = x0 - D.yyy;      // -1.0+3.0*C.x = -0.5 = -D.y

    // Permutations
    i = mod289(i);
    vec4 p = permute( permute( permute(
    i.z + vec4(0.0, i1.z, i2.z, 1.0 ))
    + i.y + vec4(0.0, i1.y, i2.y, 1.0 ))
    + i.x + vec4(0.0, i1.x, i2.x, 1.0 ));

    // Gradients: 7x7 points over a square, mapped onto an octahedron.
    // The ring size 17*17 = 289 is close to a multiple of 49 (49*6 = 294)
    float n_ = 0.142857142857; // 1.0/7.0
    vec3  ns = n_ * D.wyz - D.xzx;

    vec4 j = p - 49.0 * floor(p * ns.z * ns.z);  //  mod(p,7*7)

    vec4 x_ = floor(j * ns.z);
    vec4 y_ = floor(j - 7.0 * x_ );    // mod(j,N)

    vec4 x = x_ *ns.x + ns.yyyy;
    vec4 y = y_ *ns.x + ns.yyyy;
    vec4 h = 1.0 - abs(x) - abs(y);

    vec4 b0 = vec4( x.xy, y.xy );
    vec4 b1 = vec4( x.zw, y.zw );

    //vec4 s0 = vec4(lessThan(b0,0.0))*2.0 - 1.0;
    //vec4 s1 = vec4(lessThan(b1,0.0))*2.0 - 1.0;
    vec4 s0 = floor(b0)*2.0 + 1.0;
    vec4 s1 = floor(b1)*2.0 + 1.0;
    vec4 sh = -step(h, vec4(0.0));

    vec4 a0 = b0.xzyw + s0.xzyw*sh.xxyy ;
    vec4 a1 = b1.xzyw + s1.xzyw*sh.zzww ;

    vec3 p0 = vec3(a0.xy,h.x);
    vec3 p1 = vec3(a0.zw,h.y);
    vec3 p2 = vec3(a1.xy,h.z);
    vec3 p3 = vec3(a1.zw,h.w);

    //Normalise gradients
    vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
    p0 *= norm.x;
    p1 *= norm.y;
    p2 *= norm.z;
    p3 *= norm.w;

    // Mix final noise value
    vec4 m = max(0.6 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), 0.0);
    m = m * m;
    return 42.0 * dot( m*m, vec4( dot(p0,x0), dot(p1,x1), dot(p2,x2), dot(p3,x3) ) );
}













//fractal brownian motion (noise harmonic)
float fbm4(vec2 uv){
    float n = 0.5;
    float f = 1.0;
    float l = 0.2;
    for (int i=0; i<4; i++)
    {
        n += snoise(vec3(uv*f, 1.0))*l;
        f *= 2.00;
        l *= 0.65;
    }
    return n;

}


//fractal brownian motion (noise harmonic - fewer octaves = smoother)
float fbm8(vec2 uv){
    float n = 0.5;
    float f = 4.0;
    float l = 0.2;
    for (int i=0; i<8; i++)
    {
        n += snoise(vec3(uv*f, 1.0))*l;
        f *= 2.00;
        l *= 0.65;
    }
    return n;

}









vec4 detectOutside( vec2 uv )
{
    if (length(clamp(uv, vec2(0.0, 0.0), vec2(1.0, 1.0)) - uv) == 0.0)
    return vec4(texture2D(iChannel0, uv).xyz, 1.0);
    else
    return vec4(0, 0, 0, 0);

}


vec2 rotate( vec2 v, vec2 o, float a )
{
    float s = sin(a);
    float c = cos(a);
    mat2 m = mat2(c, -s, s, c);
    return m * (v-o) + o;
}


vec2 TransformPlane( vec2 uv, vec2 center, float XRot, float YRot )
{
    //around y-axis
    vec2 RayDirection =  vec2(uv.x, 0.0);
    vec2 A1 = vec2(0.0, -1.0);
    vec2 B1 = RayDirection - A1;
    vec2 C1 = rotate(vec2(-1.0, 0.0), vec2(center.x, 0.0), YRot);
    vec2 D1 = rotate(vec2( 1.0, 0.0), vec2(center.x, 0.0), YRot) - C1;
    //intersection point
    float u = ( (C1.y + 1.0) * D1.x - C1.x * D1.y ) / (D1.x*B1.y-D1.y*B1.x);
    //pos. on plane
    float sx = u * B1.x;
    float sy = u * uv.y;
    //around x-axis
    RayDirection = vec2(sy, 0.0);
    vec2 B2 = RayDirection - A1;
    vec2 C2 = rotate(vec2(-1.0, 0.0), vec2(center.y, 0.0), XRot);
    vec2 D2 = rotate(vec2( 1.0, 0.0), vec2(center.y, 0.0), XRot) - C2;
    //intersection point
    float v = ( (C2.y + 1.0) * D2.x - C2.x * D2.y ) / (D2.x*B2.y-D2.y*B2.x);
    //final pos. on plane:
    return vec2(v * sx, v * B2.x );

}


void main() {
    vec2 moveScreen = vec2(0.2, 0.1);
    vec2 rotateScreen = vec2(0.5, 0.3);
    float distanceScreen = 0.0;
    float noiseFrequency = 0.1;

    // Move with brownian noise
    rotateScreen.x = fbm4(vec2(1.0, iTime * noiseFrequency)) - 0.5;
    rotateScreen.y = fbm4(vec2(100.0, iTime * noiseFrequency)) - 0.5;
    moveScreen.x = fbm4(vec2(200.0, iTime * noiseFrequency)) - 0.5;
    moveScreen.y = fbm4(vec2(400.0, iTime * noiseFrequency)) - 0.5;
    distanceScreen = (fbm4(vec2(600.0, iTime * noiseFrequency)) - 0.5) * 3.0;

    vec2 uv = -1.0 + 2.0 * textureCoordinate;
    uv += moveScreen;

    float R_X = Max_Rotation * rotateScreen.x;
    float R_Y = Max_Rotation * rotateScreen.y;


    vec2 RotationCenter = vec2(0.0);
    RotationCenter.y += distanceScreen;

    vec2 MyCoords = TransformPlane(uv, RotationCenter, R_X, R_Y);
    vec2 MyTexCoord = (MyCoords+1.0)/2.0;

    fragColor = vec4(detectOutside(MyTexCoord.xy));
}